os만들기 - 14. 10실린더 만큼 읽기

이번에 할일

이전의 과정으로 C0-H0-S2(0x8200)에서 C0-H0-S18섹터(~0x3aff) 까지 읽음

-> 이제 C0-H1-S1로 0xa400부터 읽음.

-> C0-H1-S18까지 읽고 다음 실린더 C1-H0-S1으로 넘어가자

-> 이를 반복해서 C9-H1-S18까지 읽자

 

 

1.5mb 플로피 디스크 구성

- 디스크 1장 : 80 실린더, 2헤드

- 실린더 1개 : 18 섹터

- 섹터 1개 : 512바이트

=> 총 1,440kb

 

 

; haribote-ipl
; TAB=4

CYLS	EQU		10				; CYLS를 10으로 정의

		ORG		0x7c00			; 메모리 안에서 로딩되는 곳

; 아래는 표준 FAT12 포맷 플로피 디스켓을 위한 내용들

		JMP		entry
		DB		0x90
		DB		"HARIBOTE"		; 부트섹터 이름. 마음대로해도 ok
		DW		512				; 1섹터 크기(바이트 단위, 512)
		DB		1				; 클러스터 크기(1로 해야됨)
		DW		1				; 예약된 섹터수 
		DB		2				; 디스크 FAT 테이블 수
		DW		224				; 루트 디렉토리 엔트리 수 (보통 224엔트리)
		DW		2880			; 디스크 총섹터수
		DB		0xf0			; 미디어 타입
		DW		9				; 하나의 FAT 테이블 섹터 수
		DW		18				; 1트랙에 몇 색터가있는지
		DW		2				; 헤드의 수
		DD		0				; 파티션 없으므로 0
		DD		2880			; 드라이브 크기 한번더씀
		DB		0,0,0x29		; 필요하다고함
		DD		0xffffffff		; 볼륨 시리얼 번호
		DB		"HARIBOTEOS "	; 디스크 이름
		DB		"FAT12   "		; 포멧이름
		RESB	18				; 18바이트 남김

; 프로그램 본체

entry:
		MOV		AX,0			; 레지스터 초기화
		MOV		SS,AX
		MOV		SP,0x7c00
		MOV		DS,AX

; 디스크 읽기

		MOV		AX,0x0820
		MOV		ES,AX
		MOV		CH,0			; 실린더 0
		MOV		DH,0			; 헤드 0
		MOV		CL,2			; 섹터 2 
readloop:
		MOV		SI,0			; 실패 횟수를 세는 레지스터
		
retry:
		MOV		AH,0x02			; AH=0x02 : 디스크 읽기
		MOV		AL,1			; 1 섹터
		MOV		BX,0
		MOV		DL,0x00			; A 드라이브
		INT		0x13			; 디스크 바이오스 호출
		JNC		next			; 에러가 없으면 next로
		ADD		SI,1			; SI에 1더하기
		CMP		SI,5			; SI와 5비교
		JAE		error			; SI >= 5 이면 에러로
		MOV		AH,0x00
		MOV		DL,0x00			; A 드라이브
		INT		0x13			; 드라이브 리셋
		JMP		retry
next:
		MOV		AX,ES			; 어드레스를 0x200 더함
		ADD		AX,0x0020
		MOV		ES,AX			; ADD ES,0x020이 없어서 이렇게 함
		ADD		CL,1			; CL에 1 더함
		CMP		CL,18			; CL과 18 비교
		JBE		readloop		; CL <= 18 readloop로
		MOV		CL,1
		ADD		DH,1
		CMP		DH,2
		JB		readloop		; DH < 2 read loop로
		MOV		DH,0
		ADD		CH,1
		CMP		CH,CYLS
		JB		readloop		; CH < CYLS read loop로

fin:
		HLT						; CPU 정지 시킴
		JMP		fin				; 무한 루프

error:
		MOV		SI,msg

putloop:
		MOV		AL,[SI]
		ADD		SI,1			; SI에 1 더함
		CMP		AL,0
		JE		fin
		MOV		AH,0x0e			; 한 문자 표시 기능
		MOV		BX,15			; 컬러 코드
		INT		0x10			; 비디오 BIOS 호출
		JMP		putloop

msg:
		DB		0x0a, 0x0a		; 줄바꿈 문자 2개
		DB		"load error"
		DB		0x0a			; 줄바꿈
		DB		0

		RESB	0x7dfe-$		; 나머지칸 0채우기

		DB		0x55, 0xaa

 

 

 

추가된 내용

1. 섹터 18까지 리드 루프

2. 섹터 18 넘어가면 섹터 =1, 헤더++, 헤더가 2인지 확인 => 헤더가 1이면 리드루프로

3. 섹터 18 넘고, 헤더도 2가 되면 => 헤더 = 0,  실린더++

4. 실린더가 10(CYLS)보다 작은 경우에만 read loop

5. 실린더가 10이되면 fin 레이블로 넘어가 종료

 

 

EQU 명령

- C언어의 #define과 동일

- EQU 는 equal의 약어

- CYLS EQU 10 => CYLS = 10

 

 

현황

- 부트섹터 코드 대부분 완성

- 10(실린더) x 2(헤더) x 18(섹터) x 512(바이트) = 184,320(바이트) = 180KB까지 읽을수 있게됨

- PC 메모리의 0x8200~0x34ffff는 디스크에서 읽은 데이터들로 꽉 차게됨